multiply_arrays Module Function

  module function multiply_arrays(a, b) result(c)
    !! Multiply two autodiff arrays (element-wise)
    implicit none
    class(array_type), intent(in), target :: a, b
    type(array_type), pointer :: c

    integer :: i, s

    if(b%is_scalar)then
       c => a%create_result()
       c%val = a%val * b%val(1,1)
    elseif(.not.b%is_sample_dependent)then
       c => a%create_result()
       do concurrent(s = 1:size(a%val,2), i = 1:size(a%val,1))
          c%val(i,s) = a%val(i,s) * b%val(i,1)
       end do
    elseif(.not.a%is_sample_dependent)then
       c => b%create_result()
       do concurrent(s = 1:size(b%val,2), i = 1:size(b%val,1))
          c%val(i,s) = a%val(1,1) * b%val(i,s)
       end do
    elseif(size(a%val,1).ne.size(b%val,1).and.size(a%val,2).eq.size(b%val,2))then
       if(size(a%val,1) .eq. 1)then
          c => b%create_result()
          do concurrent(s = 1:size(a%val,2), i = 1:size(b%val,1))
             c%val(i,s) = a%val(1,s) * b%val(i,s)
          end do
       elseif(size(b%val,1) .eq. 1)then
          c => a%create_result()
          do concurrent(s = 1:size(a%val,2), i = 1:size(a%val,1))
             c%val(i,s) = a%val(i,s) * b%val(1,s)
          end do
       end if
    else
       c => a%create_result()
       c%val = a%val * b%val
    end if

    c%get_partial_left => get_partial_multiply_left
    c%get_partial_right => get_partial_multiply_right
    c%get_partial_left_val => get_partial_multiply_left_val
    c%get_partial_right_val => get_partial_multiply_right_val
    c%get_partial_left_val_sum => get_partial_multiply_left_val_sum
    c%get_partial_right_val_sum => get_partial_multiply_right_val_sum
    if(a%requires_grad .or. b%requires_grad)then
       c%requires_grad = .true.
       c%is_forward = a%is_forward .or. b%is_forward
       c%operation = 'multiply'
       c%left_operand => a
       c%right_operand => b
       c%owns_left_operand = a%is_temporary
       c%owns_right_operand = b%is_temporary
    end if
  end function multiply_arrays