subtract_arrays Module Function

  module function subtract_arrays(a, b) result(c)
    !! Subtract two autodiff arrays
    implicit none
    class(array_type), intent(in), target :: a, b
    type(array_type), pointer :: c

    integer :: i, s

    c => a%create_result()
    if(.not.b%is_sample_dependent)then
       do concurrent(s = 1:size(a%val,2), i = 1:size(a%val,1))
          c%val(i,s) = a%val(i,s) - b%val(i,1)
       end do
    else
       do concurrent(s = 1:size(a%val,2), i = 1:size(a%val,1))
          c%val(i,s) = a%val(i,s) - b%val(i,s)
       end do
    end if

    c%get_partial_left => get_partial_add
    c%get_partial_right => get_partial_negate
    c%get_partial_left_val => get_partial_add_val
    c%get_partial_right_val => get_partial_negate_val
    c%get_partial_left_val_sum => get_partial_add_val_sum
    c%get_partial_right_val_sum => get_partial_negate_val_sum
    if(a%requires_grad .or. b%requires_grad)then
       c%requires_grad = .true.
       c%is_forward = a%is_forward .or. b%is_forward
       c%operation = 'subtract'
       c%left_operand => a
       c%right_operand => b
       c%owns_left_operand = a%is_temporary
       c%owns_right_operand = b%is_temporary
    end if
  end function subtract_arrays