power_real_scalar Module Function

  module function power_real_scalar(a, scalar) result(c)
    !! Raise autodiff array to scalar power
    implicit none
    class(array_type), intent(in), target :: a
    real(real32), intent(in) :: scalar
    type(array_type), pointer :: c
    type(array_type), pointer :: b_array

    integer :: i, s

    c => a%create_result()
    do concurrent(s = 1:size(a%val,2), i = 1:size(a%val,1))
       c%val(i,s) = a%val(i,s) ** scalar
    end do

    c%get_partial_left => get_partial_power_base
    c%get_partial_left_val => get_partial_power_base_val
    c%get_partial_left_val_sum => get_partial_power_base_val_sum
    if(a%requires_grad)then
       c%requires_grad = .true.
       c%is_forward = a%is_forward
       c%operation = 'power_scalar'
       c%left_operand => a
       c%owns_left_operand = a%is_temporary
    end if
    allocate(b_array)
    b_array%is_scalar = .true.
    b_array%is_sample_dependent = .false.
    b_array%requires_grad = .false.
    call b_array%allocate(array_shape=[1, 1])
    b_array%val(1, 1) = scalar
    c%right_operand => b_array
    c%owns_right_operand = .true.

  end function power_real_scalar